ARCHIV

Gnuplot 3 - datové soubory

Tento díl se bude zabývat možnostmi programu Gnuplot při zpracování souborů dat.

5.10.2004 08:00 | Vladimír Jarý | Články autora | přečteno 27591×

Nejprve bych měl zmínit strukturu datových souborů. Jedná se o obyčejné textové soubory, jednotlivé datové řady jsou ve sloupcích oddělených mezerou nebo tabulátorem. Řádek začínající křížkem se bere jako komentář, prázdný řádek znamená nespojitost grafu. Oddělovačem desetinných míst je tečka.

Jako první příklad nám poslouží data získaná v průběhu 24 hodin meteorologickou stanicí - první sloupec datového souboru obsahuje číslo měření, druhý čas měření, ve třetím je zaznamenána teplota, ve čtvrtém atmosferický tlak a v posledním vlhkost vzduchu. Pro vykreslení dat ze souboru se použije nám již dobře známá funkce plot, tentokráte s parametrem obsahujícím název souboru:

 plot "meteo.dat"

Jméno souboru musí být uzavřené v uvozovkách a může obsahovat i cestu k souboru. Bez udání dalších parametrů se vykreslí závislost datové sady ve druhém sloupci na datech prvního sloupce (v našem případě tedy závislost času na čísle měření). Toto chování se nám teď nehodí, proto použijeme další parametr using x:y, který vykreslí závislost veličiny ve sloupci y na sloupci x. Následující ukázka nakreslí denní průběh teploty:

plot "meteo.dat" using 1:3 title "Prubeh teploty"
plot "meteo.dat" using 3:4 title "Zavislost tlaku na teplote"

Nyní se pokusíme na osu x místo čísla měření nanést čas měření. Nejprve zavoláme příkaz set timefmt "formát", který programu gnuplot sdělí formát vstupních dat. Následuje seznam formátovacích výrazů:

V našem ukázkovém souboru je čas psán ve tvaru hodina:minuta, použijeme tedy:

set timefmt "%H:%M"

Před vykreslením grafu ještě nastavíme měřítko osy x na práci s časem:

set xdata time

a nyní již můžeme graf vykreslit:

plot "meteo.dat" using 2:3

Ještě zbývá upravit formát osy x:

set format x "%H:%M"
replot
set xrange ["12:00":"20:00"] # průběh teploty od 12.00 do 20.00
replot

Pokud bychom potřebovali vytvořit z dat spojitý graf, můžeme změnit styl kreslení:

set style data lines # kreslení dat spojitou čarou
replot

set style nastaví kreslení na jednu z kategorií data, function, line, fill, arrow; poslední parametr nastaví konkrétní typ kreslení. Pro seznam vypsání všech režimů napište pouze set style data. V ukázce jsem tedy specifikoval, že se budou vykreslovat data spojitou čárou. Později v dnešní lekci ještě zmíním chybové úsečky.

Sekundární měřítko

Nyní se pokusíme do jednoho grafu vtěsnat průběh teploty a tlaku. Podobně jako u kreslení funkcí, i zde se jednotlivé datové sady oddělují čárkou:

plot "meteo.dat" using 1:3 title "Prubeh teploty",
     "meteo.dat" using 1:4 title "Prubeh tlaku"

Vzhledem k faktu, že ve veličinách teplota a tlak je řádový rozdíl, je náš graf poněkud nicneříkající. Problém vyřešíme definováním pomocného měřítka pro jednu z veličin - parametr axes x2y2.

plot "meteo.dat" using 1:3 title "Prubeh teploty",
     "meteo.dat" using 1:4 axes x2y2 title "Prubeh tlaku"
set y2tics # zapne hodnoty na sekundární ose
replot

Počítání průměru

Ve druhém ukázkovém souboru jsou data z devíti měření na 5 lokalitách A-E, ve zvláštních sloupcích jsou minimální a maximální hodnoty měření (pokud Vám to pomůže, můžete si představit, že se jedná o test 5 počítačových sestav v ripování audio CD o 9 stopách). Na začátek vyneseme do grafu výsledky všech 5 sestav:

# příkaz musí být zadán jako 1 řádek
plot "bench.dat" using 1:2 title "PC 1",
	   "bench.dat" using 1:3 title "PC 2",
	   "bench.dat" using 1:4 title "PC 3",
	   "bench.dat" using 1:5 title "PC 4",
	   "bench.dat" using 1:6 title "PC 5"

Nyní ke grafu přidáme datovou sadu obsahující minimální a maximální hodnoty:

replot "bench.dat" using 1:7 with lines title "Minimum",
	     "bench.dat" using 1:8 with linespoints title "Maximum"

Modifikátor příkazu with způsobí změnu stylu vykreslování, ale pouze pro aktuální datovou sadu, na rozdíl od příkaz set style. Nyní se pokusíme vytvořit novou datovou sadu obsahující průměrný výkon všech 5 testovaných počítačů. Klíčem k vyřešení problému je modifikátor using, který nemusí obsahovat přímo zadané číslo sloupce, ale i výrazy:

plot "bench.dat" using 1:($2+$3+$4+$5+$6)/5 with boxes title "Prumerny vykon"
set xtics ("Stopa 1" 1, "Stopa 2" 2,
           "Stopa 3" 3, "Stopa 4" 4, 
           "Stopa 5" 5, "Stopa 6" 6,
           "Stopa 7" 7, "Stopa 8" 8,
           "Stopa 9" 9)
replot

Operátor $ použitý na prvním řádku funguje s číslem sloupce jako proměnná obsahující data v daném sloupci, výraz ($2+$3+$4+$5+$6)/5 tedy opravdu vypočítá aritmetický průměr. Podobně by se daly vypočítat i další statistické ukazatele. Příkaz na druhém řádku nastaví popisky na ose x, pro návrat do původního stavu:

set xtics 1 #nastav vzdálenost značek na ose x na 1

Nyní se podíváme na další možnost využití modifikátoru using, zatím jsme jej používali pouze se dvěma parametry - datovou sadou pro osu x a pro osu y. Pokud nastavíme styl kreslení na errorbars (chybové úsečky), potom bude mít třetí parametr význam minimálních hodnot a čtvrtý maximálních hodnot. Za první parametr zvolíme číslo stopy (první sloupec souboru) a za druhý zvolíme průměr. Připomínám, že v 7 sloupci našeho datového souboru jsou minimální a v 8. maximální hodnoty.

plot "bench.dat" using 1:($2+$3+$4+$5+$6)/5:7:8 with errorbars title "Odchylky od prumeru"

Pro lepší představu si můžete do grafu příkazem replot přikreslit datové sady pro minimální, maximální a průměrné hodnoty.

Kreslení "třírozměrných" datových souborů

Pro vykreslení datového souboru ve 3d se použije příkaz splot "soubor". Z adresáře s ukázkovými příklady (na Slackware 9.1: /usr/doc/gnuplot-4.0.0/demo) si překopírujte soubory world.dat a world.cor. Nejprve vykreslíme data ve 2d:

plot [-180:180][-90:90] "world.dat" with lines

Nyní provedeme projekci na povrch koule:

set parametric # parametrické zadávání
set angles degrees # zadávání ve stupních
set isosamples 9,18 # kvalita
set urange [-90:90] # šířka
set vrange [0:360] # délka
set size ratio 1
plot cos(u)*cos(v),cos(u)*sin(v),sin(u) with lines # jednotková koule
set mapping spherical # nanášení na povrch koule
replot 'world.dat' with lines # vykreslení dat

a na povrch válce:

set mapping cylindrical # nanášení na povrch válce
set urange [-180:180] # zeměpisná délka
set vrange [-90:90] # zeměpisná šířka
splot cos(u),sin(u),v with lines # rovnice válvoé plochy
replot 'world.dat' with lines # přikreslení dat

A to je vše. K dnešní lekci si můžete stáhnout použité datové soubory.

Verze pro tisk