Dnes si představíme dva moduly z archivu CPAN, které dovedou využít internetových služeb FTP a POP3.8.4.2009 06:00 | Jiří Václavík | přečteno 14386×
Dnes si představíme dva moduly z archivu CPAN, které dovedou využít internetových služeb FTP a POP3.
8.4.2009 06:00 | Jiří Václavík | přečteno 14386×
Existuje několik modulů, které poskytují rozhraní pro komunikaci s některými síťovými službami. Můžeme si tím pádem vytvořit jednoduché emailové klienty nebo FTP klienty.
FTP je protokol, který, jak již je z názvu File Transfer Protocol patrné, umožňuje pohodlný přenos dat mezi počítači. Funguje na mechanizmu klient - server. Pro Perl je v archivu CPAN k dispozici modul nazvaný Net::FTP, jež právě FTP komunikaci poskytuje.
Na příkladu si ukážeme, jak se připojit k nějakému vzdálenému serveru a jak z něj získávat a posílat mu data.
Abychom si mohli vyzkoušet funkce, jež budeme dále popisovat, je třeba mít nějaký vzdálený počítač, kam se budeme moci přes FTP připojit. Dále budu předpokládat, že máme server ftp.server.cz, na kterém existuje uživatel user s heslem pAssW0Rd.
Práce s modulem Net::FTP zahrnuje několik kroků. Jsou to následující.
Ze všeho nejdříve vytvoříme proměnné s přihlašovacími údaji.
use Net::FTP;
my $hostname = "ftp.server.cz";
my $username = "user";
my $password = "pAssW0Rd";
Dále již můžeme volat FTP server. Vytvoříme tedy instanci modulu Net::FTP.
my $ftp = Net::FTP->new($hostname) or die "Nelze se spojit s FTP serverem. ";
A nyní se přihlásíme.
$ftp->login($username, $password) or die "Nelze se přihlásit. ";
V tomto okamžiku jsme ve spojení se serverem. Pokud znáte shellový příkaz ftp, tak pro vás nebudou další informace již ničím novým. Metody modulu Net::FTP mají totiž stejné názvy jako příkazy nástroje ftp.
Nejdříve si představíme metody pro práci s adresářovou cestou. Funkce cwd mění aktuální adresář - tedy funguje podobně jako příkaz cd v shellu.
$ftp->cwd("pub") or die "Nelze změnit adresář. "; #nyní jsme na serveru v adresáři /pub
Budeme-li naopak chtít jméno aktuálního adresáře získat a vytisknout, použijeme příkaz pwd.
print $ftp->pwd; #tiskne /pub
Příkazy ls a ls -l pro výpis obsahu adresáře jsou v příkazovém řádku nepostradatelnými. Modul Net::FTP nám samozřejmě poskytuje i příkazy, které jsou jejich analogiemi. Začneme jednodušším ls. Následující úsek kódu uloží do pole názvy souborů v aktuálním adresáři na serveru a následně každý z nich vytiskne na samostatný řádek.
my @ls = $ftp->ls(".") or die "Nelze získat seznam souborů \n";
$" = "\n";
print "@ls\n";
Uvedení parametru není pro získání obsahu aktuálního adresáře nezbytné. Jinak lze zadat libovolný dostupný adresář na serveru.
Implementace příkazu ls -l je stejná až na to, že místo metody ls se použije dir.
my @ls = $ftp->dir(".") or die "Nelze získat seznam souborů \n";
$" = "\n";
print "@ls\n";
Nyní se dostáváme k tomu nejdůležitějšímu. Protokol FTP se využívá právě pro přenos souborů. Můžeme posílat soubory na server, ale také stahovat. Slouží k tomu dvě jednoduché metody: get a put.
Již z názvu je patrné, že put provádí upload souboru na server. Budeme-li chtít poslat soubor letter.txt uložený v aktuálním adresáři lokálního stroje do aktuálního adresáře na server, použijeme následující příkaz.
$ftp->put("./letter.txt") or die "Nelze provést upload. \n";
Pro tok dat opačným směrem, tedy ze serveru na klienta, použijeme funkci get.
$ftp->get("send.php") or die "Nelze provést download. \n";
A nakonec uzavřeme spojení.
$ftp->quit;
Existují samzřejmě další a další příkazy a pokročilejší funkce, ale když o ně někdo bude mít zájem, jistě už sám nahlédne do dokumentace.
Další službou, ke které se pokusíme pomocí Perlu přistupovat, bude email. POP (Post Office Protocol) verze 3 je protokol, který umožňuje stahovat data z emailového serveru. Nevýhodou POP protokolu může být to, že po přečtení emailu se na serveru zpráva smaže. Je však možné přečíst pouze část zprávy a email na serveru zůstane. Další nevýhodou je to, že POP protokol stahuje všechny zprávy na serveru včetně spamu.
V Perlu poskytuje rozhraní pro POP protokol modul Net::POP3, na kterém si práci s POP3 předvedeme.
Předpokladem pro to, aby vám následující kód fungoval, je přístup k emailové adrese. Od poskytovatele emailu si je třeba si zjistit server příchozích zpráv POP3. Předpokládejme, že máme emailovou adresu user@server.cz, POP3 server je pop3.server.cz, uživatelské jméno user a heslo pAssW0Rd.
use Net::POP3;
my $hostname = "pop3.server.cz";
my $username = "user";
my $password = "pAssW0Rd";
Prvním úkolem je připojení k POP3 serveru. Zavoláme tedy konstruktor třídy Net::POP3.
my $pop = Net::POP3->new($hostname) or die "Nelze se připojit. $!\n";
Dalším krokem je přihlášení. Metoda login vrací počet nových zpráv ve schránce, takže tuto hodnotu hned přiřadíme.
my $zprav = $pop->login($username, $password) or die "Nelze se přihlásit. $!\n";
print "POČET ZPRÁV: $zprav\n\n";
Pokud nenastal nějaký problém, můžeme nyní se schránkou pracovat. Metoda list zpřístupňuje seznam zpráv.
my $r_zpravy = $pop->list() or die "Nelze získat seznam zpráv. $!\n";
Dále v cyklu zobrazíme z každé zprávy hlavičku a 5 úvodních řádků zprávy. K tomu použijeme metodu top.
foreach (keys %$r_zpravy) {
print "------------------------------------\n";
print "Zpráva číslo $_:\n";
my $r_z = $pop->top($_, 5);
print @$r_z;
}
A na úplný závěr ukončíme spojení.
$pop->quit;
Jak je vidět, práce se službami internetu není v Perlu díky modulům nic složitého. Dnes jsme si ukázali pouze služby FTP a POP3, nicméně existují moduly pro řadu dalších, které obvykle začínají prefixem Net::. Namátkou uveďme Net::IMAP a Net::HTTP.