Perl (109) - Moose - role

Perl Role jsou dalším přiblížením objektově orientovaného programování reálnému světu.

3.5.2010 00:00 | Jiří Václavík | přečteno 9711×

Pro porozumnění rolím si na začátku představme nějakého konkrétního člověka. Ten může být zároveň zaměstnancem stavební firmy, sběratelem mincí, hráčem lakrosového klubu nebo návštěvníkem divadla. To můžeme nazvat jeho rolemi. Je dobré si uvědomit, že zaměstnanec, sběratel, hráč i návštěvník jsou ve skutečnosti jediná osoba. Přitom kontakt s okolím tohoto člověka se liší v závislosti na aktuální roli. Na základě této přirozené myšlenky fungují role v objektově orientovaném programování.

Role je fyzicky soubor metod (resp. balík, který obsahuje tyto metody), které obvykle reprezentují nějaké vlastnosti. Je to něco podobného jako třída, avšak v několika věcech se tyto objekty liší.

Jedna role může spojovat několik navzájem jen vzdáleně souvisejících tříd tak, že sdílejí nějakou část chování. Všechny metody, které jsou uvnitř role definovány potom mohou být "používány" konkrétními (a samozřejmě předem určenými) třídami a chovat se jakoby byly metodami nebo atributy oněch tříd (a tedy jsou mimo jiné také děděny).

Abychom se vyhnuli omylům a zavedli jasnou terminologii, budeme pro popsané spojení role a třídy používat termín "třída pohlcuje roli" nebo "role je pohlcena třídou" (v anglicky psaných textech se vyskytuje "roles are consumed by class").

Role verzus třídy

Je tedy role třídou? Už jsme řekli, že nikoliv. Rozdíl mezi rolí a třídou je v tom, že nevytváříme instance od role. Dalším rozdílem je, že od role nedědíme. Děděny mohou být pouze její vlastnosti prostřednictvím třídy, která ji pohltila (jinými slovy podtřída třídy, která pohltila nějakou roli, získá tuto roli také).

První příklad

Co mají společného třídy Okno a Dalnice? Třeba to, že se dají opravit. Mají-li tedy obě nějakou metodu oprava, můžeme na ni navázat akce, které se provedou v souvislosti s opravou.

Předpokládejme, že každá opravitelná věc bude mít atribut potrebuje_opravu uchovávající pravdu nebo nepravdu. Proto ho naše role zadefinuje. Dále zadefinujeme nějakou metodu, která danou věc opraví. Tu nazveme oprava. Zde je kód takové role.

package LzeOpravit;
use Moose::Role;

has "potrebuje_opravu" => (
  is=>"rw",
  isa => "Bool"
);

sub oprava {
  my $self=shift;
  print "opravuji nejakou obecnou vec...\n";
  $self->potrebuje_opravu(0);
}

Roli bychom tedy měli alespoň v náznaku napsanou. Jak ji pohltit třídou? Pro tento účel existuje klíčové slovo with, které použijeme v třídách Okno a Dalnice. Pro jednoduchost nebudeme zavádět žádné nové parametry a naše třída bude tedy mít pouze tři řádky.

package Okno;
use Moose;
with "LzeOpravit";

Podobně bychom mohli vytvořit například třídu Dalnice.

Podívejme se nyní na to, jak se třída Okno používá. Příslušné objekty mají vlastní atribut a lze je opravovat.

my $stresni_okno = Okno->new("potrebuje_opravu"=>1);
print $stresni_okno->potrebuje_opravu; #tiskne 1
print $stresni_okno->oprava;           #tiskne "opravuji nejakou obecnou vec..."
print $stresni_okno->potrebuje_opravu; #tiskne 0

Detekce role

Uveďme ještě, že pomocí metody does volané nad objektem můžeme zjistit, zda třída pohlcuje danou roli. Je to analogie metody isa pro dědičnost.

print $stresni_okno->does("LzeOpravit"); #tiskne 1

Požadavky rolí na třídy

Další vlastností rolí je, že mohou po třídách, které je pohlcují, vyžadovat definici některých konkétních metod nebo atributů.

Protože oprava dané věci je většinou naprosto konkrétní věc, bude naše role chtít, aby si třída sama definovala metodu oprava (oprava okna a dálnice jsou dvě docela odlišné věci). K tomu použijeme klíčové slovo require. V důsledku můžeme z naší role metodu oprava odstranit. Nově tedy bude vypadat takto.

package LzeOpravit;
use Moose::Role;

requires "oprava";

has "potrebuje_opravu" => (
  is=>"rw",
  isa => "Bool"
);

Nyní budeme muset metodu oprava vložit do všech tříd pohlcujících naši roli. V opačném případě bychom byli svědky chybového hlášení.

'LzeOpravit' requires the method 'oprava' to be implemented by 'Okno'

Metodu oprava můžeme upravit na míru pro okno. Třída Okno bude nově vypadat takto.

package Okno;
use Moose;
with "LzeOpravit";

sub oprava {
  my $self=shift;
  print "opravuji okno...\n";
  $self->potrebuje_opravu(0);
}

Stejně tak můžeme definovat další třídy.

package Dalnice;
use Moose;
with "LzeOpravit";

sub oprava {
  my $self=shift;
  print "opravuji dalnici...\n";
  $self->potrebuje_opravu(0);
}

Nyní lze vesele vytvářet objekty typu Okno nebo Dalnice a opravovat.

Modifikátory

Pomocí modifikátorů můžeme provádět různé akce v souvislosti s voláním nějaké metody. Podívejme se na roli, která vykoná během opravy nějaké vedlejší činnosti.

package LzeOpravit;
use Moose::Role;
requires "oprava";
has potrebuje_opravu => {isa => "Bool"};

before "oprava" => sub {
  my $self=shift;
  $self->vycisli_naklady_na_opravu();
}

after "oprava" => sub {
  my $self=shift;
  $self->uklid_naradi();
}

Problémy s kolizemi při pohlcování více rolí

Funkci with lze předat i seznam názvů rolí. V případě, že má více rolí stejnou metodu, dojde ke kolizi. Ty lze řešit tak, že metody vhodně přejmenujeme. To zajistíme pomocí volání with ve speciálním tvaru.

with "PrvniRole" => {-alias => {"kolidujici_metoda" => "kolidujici_metoda1", -excludes => "kolidujici_metoda"}},
     "DruhaRole" => {-alias => {"kolidujici_metoda" => "kolidujici_metoda2", -excludes => "kolidujici_metoda"}};

Konkrétněji, pokud máme člověka hokejistu a zároveň lukostřelce, nastane nám kolize u metody vystrel. Hokejista vystřelí puk a lukostřelec šíp. Pokud pohlcujeme obě role, není volání funkce vystrel jednoznačné. Ve třídě Člověk, která pohlcuje role Hokejista a Lukostřelec tedy přímo ve with podle výše uvedeného návodu metody přejmenujeme.

Parametrem -alias tedy vytvoříme kopie k oběma funkcím vystrel a zárověň je smažeme parametrem -excludes.

with "Hokejista"   => {-alias => {"vystrel" => "vystrel_puk"}, -excludes => "vystrel"},
     "Lukostřelec" => {-alias => {"vystrel" => "vystrel_sip"}, -excludes => "vystrel"};

Více o rolích a věcech okolo se lze dočíst v dokumentaci.

Online verze článku: http://www.linuxsoft.cz/article.php?id_article=1688