Perl (121) - Wx - události

Perl Druhá polovina tutoriálu o wxPerl obsahuje především návod, jak pracovat s událostmi. Jeho aplikace je ukázána na práci s menu.

30.11.2010 00:00 | Jiří Václavík | přečteno 9764×

Zásadní nevýhodou je, že nám tlačítko vytvořené v předchozí aplikaci nefunguje tak, jak má. Dále se podíváme, jak ho pomocí správy událostí zprovoznit.

wxPerl funguje tak, že nastavuje tzv. konektory pro řízení událostí. To znamená, že pro každý typ události zde máme funkci, která nám ji obslouží.

Upravme náš program tak, aby se po kliknutí na tlačítko aplikace uzavřela. Budeme tedy chtít volat funkci exit, jakmile uživatel tlačítko stiskne.

To obnáší tři jednoduché věci.

Nás bude nyní zajímat zejména funkce EVT_BUTTON pro obsluhu tlačítek. Proto ji importujeme do třídy FrameSTlacitkem.

use Wx::Event qw(EVT_BUTTON);

Uvnitř konstruktoru ji zavoláme a napojíme pomocí ní naše tlačítko $button na podprogram konec, který v zápětí napíšeme.

EVT_BUTTON($self, $button, \&konec);

Celkem jsme tedy modifikovali třídu FrameSTlacitkem do následující podoby. Vše ostatní zůstává stejné.

package FrameSTlacitkem;
use Wx::Event qw(EVT_BUTTON);
use base "Wx::Frame";

sub new {
    my $ref = shift;
    my $self = $ref->SUPER::new(@_);
    my $panel = Wx::Panel->new($self,-1,);
    my $button = Wx::Button->new($panel, -1, "Zavrit", [10, 10], [-1, -1]);
    EVT_BUTTON( $self, $button, \&konec );
    return $self;
}

sub konec {exit;}

Jakmile nyní spustíme aplikaci a stiskneme tlačítko, vyvolá se událost a protože ji máme pomocí EVT_BUTTON napojenou na funkci konec, program skončí.

Menu - praktická ukázka použití událostí

Ukažme si, jak v aplikaci vyrobit klasické menu. Budeme postupovat velice podobně jako doposud.

Balík main bude vypadat opět stejně.

#!/usr/bin/perl -w
use strict;
use Wx;

package main;
my $app = MojeAplikace->new;
$app->MainLoop;

Balík MojeAplikace se v podstatě také příliš lišit nebude.

package MojeAplikace;
use base "Wx::App";
    
sub OnInit {
    my $frame = FrameSMenu->new(undef, -1, "Prvni aplikace", [-1000, -1000], [400, 300]);
    $frame->Show(1);
}

Zbývá nám napsat konstruktor balíku FrameSMenu. Opět samozřejmě dědíme od Wx::Frame.

package FrameSMenu;
use base "Wx::Frame";

sub new {
    my $ref = shift;
    my $self = $ref->SUPER::new(@_);

    #zde napíšeme menu

    return $self;
}

A konečně můžeme psát to, proč to celé děláme. Vytvoření menu obnáší následující.

Začněme druhým krokem. Vytvoříme si pro ukázku dvě nabídky. Nabídku vytvoříme standardním Wx::Menu a poté do ní pomocí metody Append přidáváme položky a případně pomocí AppendSeparator vkládáme oddělovače.

Dále je možné používat AppendCheckItem a AppendRadioItem pro checkbuttony a radiobuttony. Taktéž lze vytvářet submenu pomocí AppendSubMenu (to obnáší vytvoření nabídky pomocí Wx::Menu, pro kterou poté pomocí AppendSubMenu vytvoříme položku v menu).

Standardní nabídka Soubor může vypadat například nějak takto.

my $menu1 = Wx::Menu->new();
$menu1->Append(1, "&Otevrit\tC-o","Otevrit");
$menu1->Append(2, "&Ulozit\tC-s","Ulozit");
$menu1->AppendSeparator();
my $menu_konec = $menu1->Append(-1, "&Konec\tC-x","Konec");

Pro komplexnější představu si vytvořme ještě nabídku Nápověda.

my $menu2 = Wx::Menu->new();
$menu2->Append(4, "&O programu","O programu");

Tímto je druhý krok hotov. Ještě jsme nevytvořili menubar, což učiníme právě teď. Menubar je schován v třída Wx::MenuBar a metodou Append do něj vkládáme již existující nabídky. Použití je tedy v našem případě následující.

my $menubar = Wx::MenuBar->new();
$menubar->Append($menu1, "&Soubor");
$menubar->Append($menu2, "&Napoveda");

Zbývá nám aktivovat menubar. K tomu máme metodu SetMenuBar.

$self->SetMenuBar($menubar);

Nyní bychom samozřejmě měli jednotlivým položkám v menu přiřadit nějakou činnost. Ukažme si, jak bychom rozchodili položku Konec v nabídce Soubor.

Nejprve je třeba importovat potřebné akce z Wx::Event. To se udělá stejně jako jsme to dělali u akcí pro tlačítka. Importujme tedy EVT_MENU.

use Wx::Event qw(EVT_MENU);

A nyní již jen přímočaře voláme EVT_MENU a definujeme požadovanou akci.

EVT_MENU($self, $menu_konec, sub{$_[0]->Close(1)});

Celý balík FrameSMenu tedy vypadá takto.

package FrameSMenu;
use Wx::Event qw(EVT_MENU);
use base "Wx::Frame";

sub new {
    my $ref = shift;
    my $self = $ref->SUPER::new(@_);

    my $menu1 = Wx::Menu->new();
    $menu1->Append(1, "&Otevrit\tC-o","Otevrit");
    $menu1->Append(2, "&Ulozit\tC-s","Ulozit");
    $menu1->AppendSeparator();
    my $menu_konec = $menu1->Append(-1, "&Konec\tC-x","Konec");

    my $menu2 = Wx::Menu->new();
    $menu2->Append(4, "&O programu","O programu");

    my $menubar = Wx::MenuBar->new();
    $menubar->Append($menu1, "&Soubor");
    $menubar->Append($menu2, "&Napoveda");

    $self->SetMenuBar($menubar);

    EVT_MENU($self, $menu_konec, sub{$_"[0]->Close(1)});

    return $self;
}

Po spuštění lze spatřit náš výtvor.

Takto vypadá naše menu

Informativní okno

Rozšiřme ještě předchozí příklad a zprovozněme položku O programu v druhé nabídce našeho menu. Chceme, aby po kliknutí na tuto položku vyskočilo nějaké okno se zprávou.

Nejprve tedy standardně vytvoříme v konstruktoru akci.

    EVT_MENU($self, 4, \&oprogramu);

A následně již stačí jen vytvořit podprogram oprogramu. Zprávu zobrazíme intuitivním použitím widgetu Wx::MessageBox.

sub oprogramu {
    my $self = shift;
    Wx::MessageBox("Toto je ukazkovy program", "O programu", "", $self);
}

Takto bude vypadat popup okno.

Informativní okno Wx::MessageBox

Online verze článku: http://www.linuxsoft.cz/article.php?id_article=1764