#!/usr/bin/env perl
use strict;
use warnings;
use Benchmark qw(:all :hireswallclock);
my $r = 100;	# string parts repeat
my $i = 1000;	# grep repeats
my $l = -2;	# test for 2 seconds
my $str = 'euiwghiweuh'x$r . 'Perl5' . 'wehjdiuh'x$r . 'Perl6' . 'weiuhiwhjh'x$r; # make string
my %regexps = (	# tested regexps
		first => qr/Perl(5|6)/o,
		second => qr/Perl5|Perl6/o,
		first_nomatch => qr/Perl(?:5|6)/o,
	);
sub makeRegexpTests (\%) {				# make hash of tests from regexps
	map {						# make pairs 'regexp_name' => sub { regexp testing }
		my $re = $regexps{$_};			# store regexp in local variable
		$_,					# regexp name ( return ('regexp_name', testing function) )
		sub {					# testing function
			for (my $c = 0; $c < $i; $c++) {
				$str =~ m/$re/g;	# here can't use $regexps{$_} because value wasn't finded in compile time
			};
		}
	} keys %{$_[0]}
}
cmpthese(
		$l,				# how long/repeats tests
		{ makeRegexpTests %regexps },	# tests
	);

#!/usr/bin/env perl
use strict;
use warnings;
use Benchmark qw(:all :hireswallclock);
my $l = -2;				# test for 2 seconds
my @testParams = (
		{r=>1, i=>100000},	# r=>string parts repeats, i=>grep repeats
		{r=>10, i=>10000},
		{r=>100, i=>1000},
	);
my %regexps = (				# tested regexps
		first => qr/Perl(5|6)/,
		second => qr/Perl5|Perl6/,
		first_nomatch => qr/Perl(?:5|6)/,
	);
sub testString ($) {			# make testing string
	my ($r) = @_;
	'euiwghiweuh'x$r . 'Perl5' . 'wehjdiuh'x$r . 'Perl6' . 'weiuhiwhjh'x$r
}
sub makeRegexpTest ($$$) {		# make test function
	my ($str, $re, $i) = @_;	# localize parameters for use in testing function
	sub {				# testing function (here $str, $re, $i like constants - see perlsub(1))
		for (my $c = 0; $c < $i; $c++) {
			$str =~ m/$re/g;
		};
	}
}
foreach ( @testParams ) {
	my ($r, $i) = @$_{qw(r i)};
	print "r: $r, i: $i$/";
	cmpthese(
			$l,										# how long/repeats tests
			{ map +($_, makeRegexpTest testString $r, $regexps{$_}, $i), keys %regexps },	# tests
		);
}