FCL nám mimo jiného umožňuje jednoduše používat XML soubory pro ukládání konfigurace, a právě tímto tématem bych začal naše vyprávění o XML ve Free Pascalu. Bohužel není FCL příliš kvalitně dokumentována a nejlepším zdrojem informací jsou tedy přímo zdrojové kódy. Vězte tedy, že většina tříd týkajících se XML se nachází v jednotkách ležících v adresáři fcl/xml/ zdrojových kódů Free Pascal Compileru (které instalátor implicitně nainstaluje do /usr/local/src/fpc-číslo-verze).

My se dnes budeme zabývat třídou TXMLConfig z jednotky xmlcfg. Ta nám velmi jednoduše umožní mít hierarchickou konfiguraci v dokumentu XML (což vlastně není podstatné). Vlastní dokument vypadá tak, že v kořenovém elementu <CONFIG /> jsou jednotlivé tagy v závislosti na názvech našich konfiguračních parametrů. Může to vypadat například takto:

<?xml version="1.0"?>
<CONFIG>
  <xmlconfig name-prompt="Name:" value-prompt="New value:"/>
  <editor default-extension="txt">
    <auto-save enabled="true" interval="5"/>
    <assembler-mode default-style="Microchip" name-regexp="^.*\.s$"/>
  </editor>
  <environment temp-dir="/var/tmp/"/>
</CONFIG>

Struktura je doufám v celku jasná, cesta k položce postupně tvoří názvy elementů a poslední část je názvem atributu. Drobnou nevýhodou tohoto formátu je, že se v určitých situacích poněkud hůře zpracovává, ale to nám pro účely uložení konfiguračních údajů může být vcelku jedno. Pokud bychom ovšem chtěli ukládat nějaké seznamy nebo něco podobného, je načase poohlédnout se po jiném řešení.

Podívej me se nyní, jaké metody a vlastnosti nám vůbec třída TXmlConfig nabízí:

V první řadě je to konstruktor Create:

constructor Create(const AFilename: String);

Jeho parametr určuje jméno souboru, ze kterého se načte a do kterého se později uloží konfigurace. Není doufám potřeba připomínat, že instance vytvořená konstruktorem se musí, až přestane být potřeba, uvolnit voláním destruktoru Free, jenž v tomto případě i zajistí zapsání konfigurace zpět do souboru.

Dále je zde metoda Flush, která nemá žádné parametry. Voláním této metody zajistíme okamžité zapsaní konfiguračního souboru na disk.

Dále jsou zde tři varianty přetížené metody GetValue, kterými se (překvapivě) dotazujeme na nastavení dané položky v souboru:

function GetValue(const APath, ADefault: String): String;
function GetValue(const APath: String; ADefault: Integer): Integer;
function GetValue(const APath: String; ADefault: Boolean): Boolean;

Všechny fungují stejně: zkusí najít hodnotu určenou parametrem APath v konfiguračním souboru (respektive v jeho paměťové reprezentaci tj. v DOM stromu). Pokud ji najdou, vrátí ji, pokud ne, vrátí hodnotu určenou parametrem ADefault. Funkce pro typ Integer a Boolean pouze obalují první funkci potřebnou konverzí z řetězce.

A když máme metody pro zjištění nastavení, chtělo by to i metody pro jeho změnu:

procedure SetValue(const APath, AValue: String);
procedure SetValue(const APath: String; AValue: Integer);
procedure SetValue(const APath: String; AValue: Boolean);

Funkce nastaví danou položku na určitou hodnotu. To znamená: Pokud položka již existuje, tak jí přepíše. Pokud neexistuje dojde k jejimu vytvoření, tudíž se postupně hledají položky cesty a neexistující se vytvářejí, nakonec se nastaví odpovídající atribut (Ve skutečnosti to funguje poněkud jinak, ale tento popis je dle mého názoru pochopitelnější a výsledek je stejný).

Možná se divíte, že neexistuje způsob jak položku smazat. Pravdou je, že mazání v takovéto struktuře je poněkud složitější úkol a autoři nejspíše necítíli potřebu tuto možnost implementovat.

Třída TXMLConfig disponuje dvěma vlastnostmi. Jednak vlastností pouze pro čtení Modified, která indikuje, zda-li byla reprezentace konfigurace v paměti změněna (a tudíž potřebuje zapsat na disk). Druhou vlastností je FileName. Čtením zjistíme název odpovídajícího souboru s konfigurací a zápisem můžeme tento soubor změnit. Změna způsobí uložení aktuálního souboru a nové načtení konfigurace z nového souboru, není to tedy cesta, jak načíst konfiguraci ze souboru A a uložit do B, na to již musíme použít jiné prostředky.

I tentokráte jsem si připravil jednoduchou ukázku použití této třidy:

uses xmlcfg;
var
  pName : string;
  pValue : string;
  cfg : TXMLConfig;
begin
  cfg := TXMLConfig.Create('xmlconfig.xml');
  repeat
    write(cfg.GetValue('xmlconfig/name-prompt','Jmeno:'));
    readln(pName);
    if pName=#27 then break;
    writeln(pName,' = ',cfg.GetValue(pName,'< nic >'));
    write(cfg.GetValue('xmlconfig/value-prompt','Nova hodnota:'));
    readln(pValue);
    if pValue=#27 then continue;
    cfg.SetValue(pName,pValue);
  until false;
  cfg.Flush;
  cfg.Free;
end.

Tento program načte soubor xmlconfig.xml a v cyklu se ptá na cestu k položce, kterou si přejeme zobrazit nebo změnit, položku zobrazí a zeptá se na její novou hodnotu, pokud zadáme pouze Escape a odřádkujeme, položka zůstane nezměněna.Stejně tak program ukončíme zadáním Escape místo cesty. (Ano, hodnota #27 znamená Escape)

Zdrojový kód třídy TXmlConfig může mimo jiného sloužit jako pěkná ukázka využítí podpory DOM ve Free Pascalu, které se budeme věnovat v dalších dílech. Skoro bych i řekl, že tak byla třída hlavně myšlena, jelikož její možnosti jsou značně omezené. Dále budeme v našem vyprávění pokračovat z poněkud jiného konce. Podíváme se totiž na vrstvu pod touto třídou, vlastní Document Object Model.