AHOJ.
Prosím vás, mohla bych někoho poprosit o zdrojový kód tohoto příkladu?? Je to příklad do školy a vůbec si s ním nevím rady. Děkuji. P.S - Stačilo by, jak vytvořím to pořadí...MĚLO BY TO BÝT V TEXTOVÉM REŽIMU.


Napiště program pro výpis bodovací tabulky bodované soutěže družstev. Budete zadávat počet družstev a poté budete dotazování na body každého z nich. Výsledkem bude tabulka uvádějící kromě všech bodů také pořadí a celkový součet bodů.

./druzstva
Zadaj pocet druztiev: 10
Druzstvo 1 ma bodov: 6
Druzstvo 2 ma bodov: 14
Druzstvo 3 ma bodov: 2
Druzstvo 4 ma bodov: 3
Druzstvo 5 ma bodov: 2
Druzstvo 6 ma bodov: 3
Druzstvo 7 ma bodov: 5
Druzstvo 8 ma bodov: 6
Druzstvo 9 ma bodov: 3
Druzstvo 10 ma bodov: 11
Miesto  Druzstvo        Bodov
1       2       14
2       10      11
3       1       6
4       8       6
5       7       5
6       4       3
7       6       3
8       9       3
9       3       2
10      5       2
Druzstva spolu ziskali 55 bodov

Zdrojak:

program druzstva;

type
	TZaznam = 
		record
			druzstvo : integer;
			bodov : integer;
		end;
		
	TZaznamy = array of TZaznam;

procedure NacitajData(var data : TZaznamy);
var i,pocet : integer;
begin
	write('Zadaj pocet druztiev: ');
	readln(pocet);
	setlength(data,pocet);
	for i:=0 to pocet-1 do
		begin
			write('Druzstvo ',i+1,' ma bodov: ');
			data[i].druzstvo := i+1;
			readln(data[i].bodov);
		end;
end;

procedure ZotriedDataPodlaPoctuBodov(var data : TZaznamy);
var 
	i : integer;
	triedene : boolean;
	pomzaznam : TZaznam;
begin
	repeat
		triedene := false;
		for i:=0 to high(data)-1 do
			if data[i].bodov < data[i+1].bodov then
				begin
					pomzaznam := data[i];
					data[i] := data[i+1];
					data[i+1] := pomzaznam;
					triedene := true;
				end;
	until not triedene;	
end;

procedure VypisData(data : TZaznamy);
var i, sucet : integer;
begin
	writeln('Miesto'#9'Druzstvo'#9'Bodov');
	sucet := 0;
	for i := 0 to high(data) do
		begin
			writeln(i+1,#9,data[i].druzstvo,#9,data[i].bodov);
			sucet := sucet + data[i].bodov;
		end;
	writeln('Druzstva spolu ziskali ',sucet,' bodov');
end;

var zaznamy : TZaznamy;

begin
	NacitajData(zaznamy);
	ZotriedDataPodlaPoctuBodov(zaznamy);
	VypisData(zaznamy);
end.

A podakovat nic? Nabuduce sa ti na to vyseriem.

:)