Již při probírání funkce system jsme se setkali s dělením procesů. Dnes se této problematice budeme věnovat podrobněji.

Proces

Proces je instancí programu. Každý proces má svoje ID (PID) - to je unikátní číslo, kterým jádro proces označuje.

Vytváření procesů

Perl obsahuje funkci fork, která se shoduje s unixovým forkem. Funkce fork vytváří dceřinný proces. Jeden program tak může běžet v několika kopiích. Po zavolání funkce fork se proces rozdvojí. Vzniknou 2 paralelní procesy - rodič a potomek. Každý s vlastním PID. Na sobě nejsou tyto procesy nijak závislé (oba mají vlastní data, jmenné prostory atd.).

Jaký to má ale všechno význam? fork se v praxi užívá k paralelnímu spuštění určitého množství kopií programu. Bez použití forku by kopie musely být spuštěny sériově.

Typickým příkladem využití je server, který zpracovává požadavky klientů. Ve stejném okamžiku server může obsluhovat více klientů zároveň. Použitím sériového zpracování by musely ostatní klienti čekat až bude hotov klient, který je právě na řadě (To může působit potíže například tehdy, když pro každého klienta musí uživatel několikkrát zadat text na vstup. Navíc klientů mohou být desítky, stovky nebo ještě více.). Až se v budoucnu budeme zabývat sockety, nějaký ukázkový server si vytvoříme.

Funkce fork nepřijímá žádný argument. Vytváří dvě totožné kopie původního programu a vrací hodnotu, kterou může být 0, PID nebo nedefinovaná hodnota. Pro potomka vrací 0, pro rodiče PID.

Příklady

Podívejme se na první úsek kódu.

my $pid = fork;                          #pro jednoduchost netestujeme na undef
printf "%-7s - %d\n", "BOD A", $pid;     #provedeno oběma procesy
if ($pid) {                              #jde o rodicovsky proces
    printf "%-7s - %d\n", "RODIC", $pid;
} else {                                 #jde o potomka
    printf "%-7s - %d\n", "POTOMEK", $pid;
}
printf "%-7s - %d\n", "BOD B", $pid;     #provedeno oběma procesy

Protože všechny procesy vypisují na stejný standartní výstup, je výsledek smíchán. V našem případě však jsou skripty tak krátké, že než druhý začne, první je už ukončen.

$ perl fork.pl
BOD A   - 0
POTOMEK - 0
BOD B   - 0
BOD A   - 8266
RODIC   - 8266
BOD B   - 8266
$

Abychom si dokázali, že běží tyto procesy paralelně, nikoliv sériově, použijeme funkci sleep. Ta přerušuje na daný počet sekund vykonávání programu.

my $pid = fork;
printf "%-7s - %d\n", "BOD A", $pid;
if ($pid) {                              #jde o rodicovsky proces
    sleep  1;                            #čekání 1s
    printf "%-7s - %d\n", "RODIC", $pid;
} else {                                 #jde o potomka
    sleep  1;                            #čekání 1s
    printf "%-7s - %d\n", "POTOMEK", $pid;
}
printf "%-7s - %d\n", "BOD B", $pid;

Výstup se nám následovně změnil.

  $ perl fork.pl
BOD A   - 0
BOD A   - 8266
POTOMEK - 0
BOD B   - 0
RODIC   - 8266
BOD B   - 8266
$

V bodě A potomek čeká a rodič ho na chvíli dožene. Potom ale čeká i rodič.

Čekání na dceřinný proces

Často se můžeme dostat do situace, kdy je dceřinný proces časově náročný a zároveň ho potřebujeme ukončit dříve, než rodičovský proces. Na to funkci sleep použít nemůžeme. Perl k tomuto účelu nabízí funkci wait nebo waitpid.

wait čeká do doby, než je ukončen libovolný z dceřinných procesů. waidpid navíc přijímá PID procesu, na jehož ukončení se čeká. Vraceno je PID ukončeného procesu.

wait i waitpid vracejí PID ukončeného potomka, na kterého se čekalo. Pokud žádný potomek neběží, vrací tyto funkce hodnotu -1.

my $pid = fork;
if ($pid) {
    print "RODIC - ZACATEK\n";
    wait; #čeká se na ukončení potomka
    print "RODIC - KONEC\n";
} else {
    print "POTOMEK - napis neco:\n";
    $_ = <STDIN>; chomp;
    print "POTOMEK - napsal jsi $_\n";
}

Odtud je zřejmé, že rodič je ukončen až po potomkovi.

$ perl fork.pl
POTOMEK - napis neco:
RODIC - ZACATEK
neconeco
POTOMEK - napsal jsi neconeco
RODIC - KONEC
$

Zjištění PID rodičovského procesu

U dceřinných procesů platí, že funkce getppid vrací PID rodiče. Pokud proces dceřinný není, vrací PID shellu, ve kterém je program spuštěn.

my $pid = fork;
if ($pid) {
    print "PREDEK RODICE(PID $$): ", getppid, "\n";
} else {
    print "PREDEK POTOMKA(PID $$): ", getppid, "\n";
}

V proměnné $$ je PID aktuálního procesu. Z následujícího výstupu lze vyčíst hierarchii procesů.

$ perl fork.pl
PREDEK POTOMKA(PID 13610): 13609
PREDEK RODICE(PID 13609):7325
$ echo $$    #PID shellu
7325
$

Spuštění jiné úlohy v procesu

Toto téma jsme již rozebírali u funkce exec. Doplňme jen, že funkce system je kombinací funkcí exec a fork.