ARCHIV

Perl (87) - CGI - příklad aplikace

Na závěr série o CGI napíšeme jednoduchou nástěnku s možností přidávání příspěvků, na čemž shrneme základní poznatky a ukážeme, jak může vypadat CGI aplikace.

7.9.2009 01:00 | Jiří Václavík | Články autora | přečteno 12652×

Abychom si zrekapitulovali předchozích 6 dílů, napíšeme si v dnešním dílu malou CGI aplikaci. Tato aplikace bude plnit úlohu nástěnky, kam bude možno pomocí formuláře přidávat další položky.

CGI skript tedy bude muset vygenerovat formulář a zobrazit dosud vložené položky. Po odeslání formuláře se stránka aktualizuje.

Ještě dodejme, že každá položka na nástěnce bude obsahovat tři údaje:

• datum a čas vložení
• autora položky
• text položky

Realizace

Datová reprezentace

Začneme jako obvykle způsobem uložení dat. Pro tento účel bude vhodným prostředkem databáze. Vytvoříme tedy tabulku s následující strukturou. Uvedeme příkaz pro databázový systém MySQL.

create table nastenka (
    id int not null primary key auto_increment,
    jmeno varchar(255),
    email varchar(255),
    text blob,
    datetime datetime
);

Sloupce jmeno, text a email jsou závislé na uživatelském vstupu. Datum a čas a id položky si bude hlídat sám skript.

Protože používáme databázi, budeme si muset osvěžit práci s modulem DBI, který byl představen v trojdílné minisérii (1, 2, 3).

CGI skript

Nyní budeme řešit už jen samotný CGI skript. Předtím, než začneme psát, si musíme ujasnit několik věcí.

• HTML stránka se bude členěna na začátek, tělo a konec. Začátek a konec stránky přitom bude definován v externím souboru. To je jeden z nejjednodušších způsobů, jak můžeme zajistit jednotnou tvář stránek (pokud bychom jich měli více).
• Než začneme, je také třeba zvolit si strategii odesílání dat klientovi. Lze buď odesílat po částech (postupně generovaný kód budeme okamžitě tisknout na standardní výstup) nebo odeslat vše najednou na konci provádění skriptu (generovaný kód budeme místo tisku ukládat). Obě varianty mají své pro a proti. My v naší aplikaci zvolíme druhou variantu.
• Použijeme neobjektové rozhraní modulu CGI.

Dále si musíme uvědomit, co vše bude na výsledné HTML stránce zobrazeno. Uděláme následující kroky.

• vygenerovat formulář
• zobrazit položky seřazené podle času vložení
• byl-li formulář odeslán, přidat do databáze položku
• vytvořit obecný HTML začátek a konec stránky

Protože jsme se rozhodli použít strategii odeslání celé stránky najednou, vytvoříme si tři proměnné, které budou obsahovat začátek a konec stránky a samotné tělo HTML dokumentu.

Víme, že začátek a konec stránky nebude v pravomoci našeho CGI skriptu, ale nějakého vnějšího modulu. Proto do něj můžeme ihned přiřadit. Obsah těla budeme do proměnné dodávat postupně.

my $zacatek = Funkce::zacatek();
my $konec = Funkce::konec();
my $telo = "";

Vytvoření formuláře

První krok zahrnuje pouze vytvoření statického HTML kódu, který vytvoří formulář. Můžeme tedy napsat toto.

$telo .= << 'FORMULAR';
<form method="post" action="/cgi-bin/projekt/nastenka.cgi">
    Jméno: <input type="text" name="jmeno"  size="30" /><br />
    Email: <input type="text" name="email"  size="30" /><br />
    <textarea name="text" rows="7" cols="40"></textarea><br />
    <input type="submit" name="akce" value="OK" />
</form>
FORMULAR

Také však lze použít funkce pro generování formulářů z CGI modulu. Generování HTML kódu tak můžeme s použitím CGI modulu přepsat do následující podoby.

$telo .= start_form(-method=>"post");
$telo .=  "Jméno: " . textfield(-name=>"jmeno", -size=>30) . br;
$telo .=  "Email: " . textfield(-name=>"email", -size=>30) . br;
$telo .=  textarea(-name=>"text", -cols=>40, -rows=>7) . br;
$telo .=  submit(-name=>"akce", -value=>"OK");
$telo .=  end_form;

Zobrazení položek nástěnky

Pod formulářem budou zobrazeny jednotlivé položky nástěnky. Dalším naším úkolem bude získat je z databáze a zobrazit. Nejprve tedy vytvoříme databázové spojení. K tomu musíme znát údaje potřebné ke spojení.

my $dbname = "project";
my $dbuser = "user";
my $dbpasswd = "";
my $dbh;

if(!($dbh = DBI->connect("dbi:mysql:dbname=$dbname", $dbuser, $dbpasswd))){
    $telo .= h1("Nastal problém.");
}

#zde získáme data a přidáme je do proměnné $telo, případně zpracujeme data

$dbh->disconnect;

Získání dat bude poměrně jednoduchá záležitost. Nejprve pošleme na databázi dotaz.

my $q = $dbh->prepare("SELECT jmeno, email, text, datetime FROM nastenka ORDER BY datetime DESC");
$q->execute;

Následně přijmeme odpověď. Zformátujeme jednotlivé položky do nějaké podoby a postupně všechny přidáme k tělu dokumentu.

while(my($jmeno, $email, $text, $datetime) = $q->fetchrow_array){
    $telo .=  hr;
    $telo .= i($datetime) . br;
    $telo .= a({-href=>"mailto:$email"}, $jmeno) . br;
    $telo .= $text;
}

Zpracování přijatých dat

Nyní nám v základním souboru ještě zbývá zaktivovat formulář. Pokud nyní odešleme data, tak se vůbec nic nestane. Je třeba, abychom v případě obdržení dat tato data uložili.

To, zda nám data přišla, poznáme podle obsahu parametrů. Tlačítko submit definuje parametr akce. Jeho existencí můžeme podmínit vykonání kódu na přidání záznamu.

Kód pro přidání položky musíme umístit před dotaz na databázi, aby byl vrácen i vložený záznam. Zároveň musí být za otevřením spojení.

Abychom zabránili vkládání prázdných záznamů, vynutíme si od uživatele zadání alespoň položek jméno a text. Pokud některá z nich zadána nebude, vypíšeme místo vložení chybovou hlášku.

if(param("akce")){
    my $jmeno = param("jmeno");
    my $email = param("email");
    my $text = param("text");
    if(!$jmeno or !$text){
        $telo .= h1("Jméno a text jsou povinné.");
    }else{
        #zadání v pořádku, zde se pokusíme vložit záznam do databáze
    }
}

Je-li vše v pořádku, zakódujeme případné nevhodné znaky z uživatelského vstupu funkcí quote a vygenerujeme aktuální čas.

        my $quoted_jmeno = $dbh->quote($jmeno);
        my $quoted_email = $dbh->quote($email);
        my $quoted_text = $dbh->quote($text);
        my @d = localtime;
        my $datetime = 1900+$d[5]."-$d[4]-$d[3] $d[2]:$d[1]:$d[0]";

Všechna data máme, poslední překážkou je poslání dat databázi.

        if($dbh->do("INSERT INTO nastenka (jmeno, email, text, datetime)
                   VALUES ($quoted_jmeno, $quoted_email, $quoted_text, '$datetime')")){
            $telo .= h1("Vloženo");
        }else{
            $telo .= h1("Nepodařilo se vložit.");
        }

Odeslání stránky

Tělo dokumentu máme hotové. Vytiskneme tedy výsledek stránky na standartní výstup. To učiníme v bloku END, neboť příkazy uvnitř něj jsou volány vždy jako poslední.

END {
    print $zacatek;
    print $telo;
    print $konec;
}

Začátek a konec stránky z externího modulu

Zbývá nám definovat funkce zacatek a konec. Rozhodli jsme se, že to bude realizováno v externím modulu, abychom jich mohli využít v příbuzných stránkách.

Do funkce zacatek zahrnmeme hlavičky dokumentu (MIME typ), HTML hlavičku a případný začátek HTML kódu za elementem BODY. Ve funkci konec bude pata dokumentu.

package Funkce;
use CGI qw(:standard);
use strict;

sub zacatek {
    my $hlavicka = header;
    $hlavicka .= start_html;
    return $hlavicka;
}

sub konec {
    $konec = end_html;
    return $konec;
}
1;

Nyní nebude problém do HTML kódu všech stránek, které používají modul Funkce zahrnout reklamní banner, jméno autora či dělat jakékoliv jiné úpravy. V takovém případě stačí funkce zacatek a konec příslušně upravit.

sub zacatek {
    my $hlavicka = header;
    $hlavicka .= start_html;
    $hlavicka .= img({-src=>"/images/banner.png"});
    return $hlavicka;
}

sub konec {
    my $konec = hr;
    $konec .= p({-align=>"center"}, "Author: xxx");
    $konec = end_html;
    return $konec;
}

Zdrojové kódy nástěnky jsou zde: Funkce.pm, nastenka.cgi.

Verze pro tisk