ARCHIV

Perl (131) - Gtk2 - transparentní okna, tray ikona, výběr souborů

Transparentní okna jsou základním kamenem pro vytváření aplikací s OSD efektem. Ty umí uživatele informovat pomocí zprávy umístěné kamkoliv do prostoru obrazovky mimo okno aplikace. Tray ikona je tlačítko na panelu v grafických prostředích, které zpřístupňuje aplikaci nebo její vybrané části.

13.4.2011 00:00 | Jiří Václavík | Články autora | přečteno 11074×

Transparentní okna - OSD aplikace

Gtk2 umí vytvářet speciální druh oken, kdy žádné okno vlastně vidět není a zobrazuje se pouze jeho obsah. Takovým aplikacím se dává přívlastek OSD (on screen display).

Zpravidla jde o zobrazování textu, ale patří sem také řadu efektů se zobrazováním obrázků. Gtk2 tyto pokročilejší záležitosti umí také.

OSD se používá často u mnoha běžných aplikací. Například u hudebních přehrávačů pro informaci o názvu skladby a interpretovi, ukazování času nebo třeba jako indikace došlých emailů či jabber zpráv.

Podíváme se, jak lze vytvářet transparentní okna v Gtk2.

use Gtk2 -init;
$okno = Gtk2::Window->new("popup");

Vytvořme kreslící plochu Gtk2::DrawingArea.

$drawing_area = Gtk2::DrawingArea->new;
$drawing_area->set_size_request(1000, 1000);
$okno->add($drawing_area);
$okno->show_all();

Do ní nastavíme to, co chceme, aby se později zobrazilo. Nastavíme zvětšený text AHOJ.

$text = $drawing_area->create_pango_layout("");
$text->set_markup("<span background='#000000' size='250000'>AHOJ</span>");
($w, $h)=$text->get_pixel_size;

Zkonvertujeme obrázek do bufferu pixelů.

$pixmap = Gtk2::Gdk::Pixmap->new($drawing_area->window, $w, $h, -1);
$pixmap->draw_layout($drawing_area->style->white_gc, 0, 0, $text);
$pixbuf = Gtk2::Gdk::Pixbuf->new ("rgb", TRUE, 8, $w, $h);
$pixbuf->get_from_drawable($pixmap, Gtk2::Gdk::Colormap->get_system, 0, 0, 0, 0, $w, $h);

Dále pixelům přidáme složku průhlednosti.

$pixbuf = $pixbuf->add_alpha (TRUE, 0, 0 , 0);

Nyní získáme masku (to je bitmapa, která určuje, které pixely jsou aktivní a které nikoliv).

($pm, $maska) = $pixbuf->render_pixmap_and_mask(255);

Na závěr tedy zvoditelníme pouze pixely z masky.

$okno->shape_combine_mask($maska, 0, 0);

Gtk2->main;

A výsledek? Takto může po spuštění aplikace vypadat levý horní roh pracovní plochy.

Část plochy po spuštění aplikace s OSD

Tray ikona

Napíšeme aplikaci, která využije místa na panelu na grafickém prostředí a vytvoří tray ikonu. Ta se běžně používá například pro přepínání jazyka, indikaci, kolik máme nepřečtených emailů, zda vyšly nové RSS zprávy, zda přišla zpráva přes jabber nebo jen pro aktivaci aplikací, které právě běží na pozadí.

Abychom mohli tray ikonu použít, musíme zvlášť modul Gtk2::TrayIcon nainstalovat.

# cpan Gtk2::TrayIcon

Poté již nic nebrání vytvoření jednoduché aplikace. Nejprve vytvoříme ikonu a pomocí EventBoxu k ní přiřadíme obrázek. To je vše, co musíme udělat.

use Gtk2 "-init";
use Gtk2::TrayIcon;

my $img= Gtk2::Image->new_from_file("./ikona.gif");
my $eventbox = Gtk2::EventBox->new;
$eventbox->add($img);

my $ikona= Gtk2::TrayIcon->new("tray");
$ikona->add($eventbox);

$ikona->show_all;

Gtk2->main;

Ještě bychom si měli ukázat, jak se vytváří akce. Po kliknutí na tray ikonu se emituje signál button-press-event. Pokud na ni jen najedeme kurzorem myši, emituje se enter-notify-event.

Tyto dvě události odchytíme. Jakmile se myš dostane do prostoru tray ikony, vypíšeme na standardní výstup informaci. Po kliknutí na tray ikonu program ukončíme.

$eventbox->signal_connect("enter-notify-event" => sub{print "Jsi v oblasti tray ikony\n";});
$eventbox->signal_connect("button-press-event" => sub{Gtk2->main_quit;});

Spusťme aplikace a podívejme se na panel. Měla by se tam objevit tray ikona.

Naše tray ikona

Vybírání souborů

K dispozici máme několik widgetů, které vyberou z adresářové struktury soubor. Představíme si Gtk2::FileChooserButton a Gtk2::FileChooserDialog.

Použití prvního je jednoduché.

my $soubor = Gtk2::FileChooserButton->new("Vyber soubor" , "open");
my $adresar = Gtk2::FileChooserButton->new("Vyber adresar" , "select-folder");

Gtk2::FileChooserDialog se používá buď pro výběr místa uložení souboru nebo pro výběr souboru, který má být otevřen. Vybereme si tedy nejprve jednu variantu. Dále se musíme rozhodnout pro tlačítka, která zobrazit.

Vytvořme si dialog pro uložení souboru s obvyklými tlačítky "OK" a "Zrušit".

my $vyber =  Gtk2::FileChooserDialog->new(
"Vyber soubor k ulozeni", undef, "save", "gtk-ok" => "ok", "gtk-cancel" => "cancel");
my $vysledek = $vyber->run;

Uživatel si vybere a výsledek obdržíme v proměnné $vysledek. Poznamenejme, že bychom měli po obdržení výsledku dialog zavřít metodou destroy.

Vybíráme, kam uložit soubor

Zajímavé je též používání filtrů. Pomocí filtru můžeme v nabídkách zobrazovat jen soubory podle určité masky nebo MIME typu.

my $filter = Gtk2::FileFilter->new();
$filter->set_name("HTML soubory");
$filter->add_mime_type("text/html");

Chceme-li použít raději masku, pak napíšeme následující.

$filter->add_pattern("*.html");
$filter->add_pattern("*.htm");

Filtr pak přidáme metodou add_filter.

$vyber->add_filter($filter)

Verze pro tisk